'From Squeak5.1 of 23 August 2016 [latest update: #16548] on 30 August 2016 at 1:07:21 pm'!

!FileList methodsFor: 'own services' stamp: 'sumim 11/22/2015 12:19'!
viewContentsInWorkspace
	"View the contents of my selected file in a new workspace"
	
	| aStringOrText aName |
	directory readOnlyFileNamed: self fullName do: [:file |
		file setConverterForCode.
		aStringOrText := (file localName endsWith: '.html') ifFalse: [
			file contentsOfEntireFile
		] ifTrue: [
			(HtmlReadWriter on: file) nextText
		].
		aName := file localName.
	].
	UIManager default edit: aStringOrText withSqueakLineEndings label: 'Workspace from ', aName! !


!HtmlReadWriter methodsFor: 'mapping' stamp: 'sumim 8/30/2016 13:05'!
mapFontTag: aTag

	| result colorStartIndex colorStopIndex attribute |
	result := OrderedCollection new.
	
	"<font color=""#00FFCC""> or <font color=""green"">"
	attribute := 'color'.
	colorStartIndex := aTag findString: attribute.
	colorStartIndex > 0 ifTrue: [
		colorStartIndex := aTag findString: '"' startingAt: colorStartIndex+attribute size.		
		colorStopIndex := aTag findString: '"' startingAt: colorStartIndex+1.
		result add: (TextColor color:
			(Color fromString: (aTag copyFrom: colorStartIndex+1 to: colorStopIndex-1)))].

	attribute := 'size'.
	colorStartIndex := aTag findString: attribute.
	colorStartIndex > 0 ifTrue: [
		| size index |
		colorStartIndex := aTag findString: '"' startingAt: colorStartIndex+attribute size.		
		colorStopIndex := aTag findString: '"' startingAt: colorStartIndex+1.
		size := [(aTag copyFrom: colorStartIndex+1 to: colorStopIndex-1) asNumber] ifError: [0].
		index := TextStyle default fontArray findFirst: [:font | font htmlSize = size].
		index ~= 0 ifTrue: [result add: (TextFontChange fontNumber: index)]].


	^ result! !

!HtmlReadWriter methodsFor: 'mapping' stamp: 'sumim 11/24/2015 17:18'!
mapTagToAttribute: aTag

	aTag = '<b>' ifTrue: [^ {TextEmphasis bold}].
	aTag = '<i>' ifTrue: [^ {TextEmphasis italic}].
	aTag = '<u>' ifTrue: [^ {TextEmphasis underlined}].
	aTag = '<s>' ifTrue: [^ {TextEmphasis struckOut}].
	"aTag = '<code>' ifTrue: [^ {TextFontReference toFont: Preferences standardCodeFont}]."
	(aTag beginsWith: '<font') ifTrue: [^ self mapFontTag: aTag].
	(aTag beginsWith: '<a') ifTrue: [^ self mapATag: aTag].

	"h1, h2, h3, ..."
	(aTag second = $h and: [aTag third isDigit])
		ifTrue: [^ {TextEmphasis bold}].

	^ {}! !


!TextEditor methodsFor: 'menu messages' stamp: 'sumim 11/22/2015 12:03'!
saveContentsInFile
	"Save the receiver's contents string to a file, prompting the user for a file-name.  Suggest a reasonable file-name."

	| fileName stringToSave parentWindow labelToUse suggestedName |
	stringToSave := paragraph text string.
	stringToSave size = 0 ifTrue: [^self inform: 'nothing to save.'].
	parentWindow := model dependents 
				detect: [:dep | dep isKindOf: SystemWindow]
				ifNone: [nil].
	labelToUse := parentWindow ifNil: ['Untitled']
				ifNotNil: [parentWindow label].
	suggestedName := nil.
	#(#('Decompressed contents of: ' '.gz')) do: 
			[:leaderTrailer | | lastIndex | 
			"can add more here..."

			(labelToUse beginsWith: leaderTrailer first) 
				ifTrue: 
					[suggestedName := labelToUse copyFrom: leaderTrailer first size + 1
								to: labelToUse size.
					(labelToUse endsWith: leaderTrailer last) 
						ifTrue: 
							[suggestedName := suggestedName copyFrom: 1
										to: suggestedName size - leaderTrailer last size]
						ifFalse: 
							[lastIndex := suggestedName lastIndexOf: $. ifAbsent: [0].
							(lastIndex = 0 or: [lastIndex = 1]) 
								ifFalse: [suggestedName := suggestedName copyFrom: 1 to: lastIndex - 1]]]].
	suggestedName ifNil: [suggestedName := labelToUse , '.text'].
	fileName := UIManager default request: 'File name?'
				initialAnswer: suggestedName.
	fileName isEmptyOrNil 
		ifFalse: [
			(fileName endsWith: '.html') ifFalse: [
				FileStream newFileNamed: fileName do: [:file |
					file nextPutAll: stringToSave
				]
			] ifTrue: [
				FileStream newFileNamed: fileName do: [:file |
					paragraph text printHtmlOn: file
				]
			]
		]
				! !


!TextEmphasis methodsFor: 'html' stamp: 'sumim 11/24/2015 17:05'!
closeHtmlOn: aStream 
	"put on the given stream the tag to close the html  
	representation of the receiver"
	emphasisCode = 1
		ifTrue: [aStream nextPutAll: '</b>'].
	emphasisCode = 2
		ifTrue: [aStream nextPutAll: '</i>'].
	emphasisCode = 4
		ifTrue: [aStream nextPutAll: '</u>'].
	emphasisCode = 16
		ifTrue: [aStream nextPutAll: '</s>']! !

!TextEmphasis methodsFor: 'html' stamp: 'sumim 11/24/2015 17:06'!
openHtmlOn: aStream 
	"put on the given stream the tag to open the html  
	representation of the receiver"
	emphasisCode = 1
		ifTrue: [aStream nextPutAll: '<b>'].
	emphasisCode = 2
		ifTrue: [aStream nextPutAll: '<i>'].
	emphasisCode = 4
		ifTrue: [aStream nextPutAll: '<u>'].
	emphasisCode = 16
		ifTrue: [aStream nextPutAll: '<s>']! !